'' 
'' このコードは、DioDocs for PDF のサンプルの一部として提供されています。
'' © MESCIUS inc. All rights reserved.
'' 
Imports System.IO
Imports System.Drawing
Imports System.Numerics
Imports GrapeCity.Documents.Pdf
Imports GrapeCity.Documents.Text
Imports GrapeCity.Documents.Drawing
Imports GrapeCity.Documents.Pdf.Annotations
Imports GrapeCity.Documents.Pdf.Actions

'' 移動先を作成し、文書本体のアウトラインノードまたは
'' リンクに関連付ける方法を示します。
Public Class Destinations
    Function CreatePDF(ByVal stream As Stream) As Integer
        Dim doc = New GcPdfDocument()

        Dim page1 = doc.NewPage()
        Dim page2 = doc.NewPage()
        Dim page3 = doc.NewPage()

        Dim mainNote = Util.AddNote(
            "これは1ページ目です。" + vbLf + vbLf + vbLf +
            "さまざまな移動先指定の例です。" + vbLf + vbLf +
            "ドキュメントのアウトラインにある移動先:" + vbLf +
            "  - 1 ページ：このページに移動し、ページ全体に合わせて表示" + vbLf +
            "  - 2 ページ：2ページ目に移動し、ページ全体に合わせて表示" + vbLf +
            "    -- ズーム率 200%: 2ページ目のメモに移動し、200%の拡大率で表示" + vbLf +
            "    -- ズーム率 100%: 2ページ目を100%で表示" + vbLf +
            "    -- 1 ページ目に移動: このページに移動" + vbLf +
            "  - 3 ページ: 3ページ目に移動し、ページ全体に合わせて表示" + vbLf +
            "    -- 3ページ目のメモにズーム: 3ページ目を表示しメモを拡大" + vbLf +
            "    -- 2 ページ目に移動: 2 ページ目に移動" + vbLf +
            "    -- 1 ページ目に移動: このページに移動" + vbLf +
            "  - 名前付き移動先: NamedDestinations辞書の名前でキー入力" + vbLf +
            "    -- ページ１" + vbLf +
            "    -- ページ２" + vbLf +
            "    -- ページ３" + vbLf + vbLf +
            "ドキュメント本体の領域に関連付けした移動先:",
            page1)
        Util.AddNote(
            "これは2ページ目です。",
            page2)
        Dim noteOnPage2 = Util.AddNote(
            "2ページ目のメモ",
            page2, New RectangleF(300, 400, 200, 300))
        Util.AddNote(
            "これは3ページ目です。",
            page3)
        Dim noteOnPage3 = Util.AddNote(
            "これは長めの文を設定したメモです。" + vbLf + "(確認用として改行を挿入)" + vbLf + "3ページ目に配置しています。",
            page3, New RectangleF(150, 440, 300, 300))

        '' アウトラインツリーの移動先。

        '' DestinationFit: ページ全体に合わせます。
        Dim on1 = New OutlineNode("1 ページ", New DestinationFit(0))
        doc.Outlines.Add(on1)

        Dim on2 = New OutlineNode("2 ページ", New DestinationFit(1))
        doc.Outlines.Add(on2)
        '' DestinationXYZ：上/左座標とズームレベル（1 は 100％）を指定できます。
        on2.Children.Add(New OutlineNode("ズーム率 200%", New DestinationXYZ(1, noteOnPage2.X, noteOnPage2.Y, 2)))
        on2.Children.Add(New OutlineNode("ズーム率 100%", New DestinationXYZ(1, Nothing, Nothing, 1)))
        '' １ページ目に戻るリンクを追加します。
        on2.Children.Add(New OutlineNode("1 ページ目に移動", New DestinationFit(0)))

        Dim on3 = New OutlineNode("3 ページ", New DestinationFit(2))
        doc.Outlines.Add(on3)
        '' DestinationFitR :ページ上に矩形を合わせます。
        on3.Children.Add(New OutlineNode("3 ページ目のメモにズーム", New DestinationFitR(2, noteOnPage3)))
        '' １ページ目と２ページ目に戻るリンクを追加します。
        on3.Children.Add(New OutlineNode("2 ページ目に移動", New DestinationFit(1)))
        on3.Children.Add(New OutlineNode("1 ページ目に移動", New DestinationFit(0)))

        '' ドキュメントの本文内の移動先（アウトラインからの移動先を再利用）。
        '' ２ページ目に移動します。
        Dim rc = Util.AddNote("2 ページ目に移動", page1, New RectangleF(72, mainNote.Bottom + 18, 200, 72))
        page1.Annotations.Add(New LinkAnnotation(rc, on2.Dest))
        '' ３ページ目に移動します。
        rc = Util.AddNote("3 ページ目に移動", page1, New RectangleF(72, rc.Bottom + 18, 200, 72))
        page1.Annotations.Add(New LinkAnnotation(rc, on3.Dest))

        '' 移動先に名前を付けて、ドキュメントの NamedDestinations 辞書に追加することもできます。
        doc.NamedDestinations.Add("ページ１", New DestinationFit(0))
        doc.NamedDestinations.Add("ページ２", New DestinationFit(1))
        doc.NamedDestinations.Add("ページ３", New DestinationFit(2))
        '' 次に、DestinationRefクラスを使用して参照できます。ここで、これらをアウトラインに追加します。
        Dim onNamed = New OutlineNode("名前付き移動先", CType(Nothing, DestinationBase))
        doc.Outlines.Add(onNamed)
        onNamed.Children.Add(New OutlineNode("名前:ページ１", New DestinationRef("ページ１")))
        onNamed.Children.Add(New OutlineNode("名前:ページ２", New DestinationRef("ページ２")))
        onNamed.Children.Add(New OutlineNode("名前:ページ３", New DestinationRef("ページ３")))
        ''
        '' PDF ドキュメントを保存します。
        doc.Save(stream)
        Return doc.Pages.Count
    End Function
End Class